!----------------------------------------------------------------------!
!  RAMSEY.TAB                                                          !
!  Nov 97 (PJW)                                                        !
!                                                                      !
!  TABLO input file for a simple Ramsey model of growth.               !
!  This version is in levels form and has updating.                    !
!----------------------------------------------------------------------!

equation    (default=levels);
variable    (default=levels);
formula     (default=initial);
coefficient (default=parameter);

!----------------------------------------------------------------------!
! Establish sets for describing periods                                !
!----------------------------------------------------------------------!
set (intertemporal) alltime size 81 ( p[0]-p[80] );
set (intertemporal) fwdtime size 80 ( p[0]-p[79] );
set (intertemporal) endtime size  1 (   p[80]  );

subset fwdtime is subset of alltime ;
subset endtime is subset of alltime ;

!----------------------------------------------------------------------!
! Variables                                                            !
!----------------------------------------------------------------------!
variable (all,t,alltime) q(t) # quantity of output    #;
variable (all,t,alltime) k(t) # capital stock         #;
variable (all,t,alltime) b(t) # production intercept  #;
variable (all,t,alltime) c(t) # consumption           #;
variable (all,t,alltime) i(t) # investment            #;

!----------------------------------------------------------------------!
! Parameters                                                           !
!----------------------------------------------------------------------!
coefficient rho   ; formula rho   = 0.05 ;
coefficient delta ; formula delta = 0.10 ;
coefficient a     ; formula a     = 0.50 ;

!----------------------------------------------------------------------!
! Base case                                                            !
!----------------------------------------------------------------------!
formula (all,t,alltime) q(t) =  3.111111 ;
formula (all,t,alltime) k(t) = 11.111111 ;
formula (all,t,alltime) b(t) =  0.222222 ;
formula (all,t,alltime) c(t) =  2.000000 ;
formula (all,t,alltime) i(t) =  1.111111 ;

!----------------------------------------------------------------------!
! Time                                                                 !
!----------------------------------------------------------------------!
file (text) time;
coefficient (all,t,alltime) year(t);
read year from file time;

coefficient (all,t,fwdtime) h(t);
formula (all,t,fwdtime) h(t) = year(t+1) - year(t);

!----------------------------------------------------------------------!
! Equations holding in all periods                                     !
!----------------------------------------------------------------------!
equation e1 (all,t,alltime) q(t) = k(t)^a - b(t) ;
equation e2 (all,t,alltime) q(t) = c(t) + i(t) ;

!----------------------------------------------------------------------!
! Dynamic equations                                                    !
!----------------------------------------------------------------------!
equation capacc (all,t,fwdtime)
   k(t+1) = k(t) + h(t)*( i(t)-delta*k(t) );

equation euleqn (all,t,fwdtime)
   c(t+1) = c(t)*( 1 + h(t)*(a*k(t)^(a-1)-rho-delta) );

!----------------------------------------------------------------------!
! Boundary conditions                                                  !
!----------------------------------------------------------------------!
equation b2 (all,t,endtime) i(t) = delta*k(t);