*
*  PROTO_BOTH.GMS 1.01
*  Oct 92 (PJW)
*
*  GAMS program to compute both base and revise case solutions 
*  for a small prototype general equilibrium model.
*

*
*  These are the model's parameters:
*

SCALAR   a   Utility function parameter     / 0.285 /;
SCALAR   b   Production function parameter  / 2.040 /;

*
*  These are exogenous variables:
*				 

SCALAR   h   Total endowment of hours       / 100.0 /;
SCALAR   t   Initial tax rate               / 0.200 /;
SCALAR   p   Numeraire price                / 1.000 /;

*
*  These are the endogenous variables:
*

VARIABLES
   y   Income
   w   Wage rate
   s   Subsidy to households
   c   Quantity consumed
   l   Labor supplied
   j   Leisure consumed
   q   Quantity produced
   z   Dummy for solver ;
				      
*
*  Here are the equations:
*
   
EQUATIONS
   income       Household income accounting identity
   consum       Household demand for goods
   leisure      Household demand for leisure
   laborsup     Household supply of labor
   labordem     Demand for labor by firms
   price        Price from firm's cost function
   govbudget    Government budget constraint
   dummy        Dummy equation for solver ;

   income..               y =e= w*h + s  ;
   consum..       p*(1+t)*c =e= a*y      ;
   leisure..            w*j =e= (1-a)*y  ;
   laborsup..           w*l =e= a*y - s  ;
   labordem..             l =e= q/b      ;
   price..                p =e= w/(b-1)  ;
   govbudget..        t*p*c =e= s        ;
   dummy..                z =e= 1000     ;
			  
*
*  The model consists of all of the equations
*
   
MODEL proto /ALL/;

*
*  Solve it using nonlinear programming.  Must give the
*  algorithm something to minimize so use a dummy variable.
*

SOLVE proto USING NLP MINIMIZING z;
	       
*
*  Now change the policy variable (t) and compute a 
*  revised case solution:
*

t = 0.300;

SOLVE proto USING NLP MINIMIZING z;