!----------------------------------------------------------------------!
!  PROTOCD.TAB 1.01                                                    !
!  Oct 99 (PJW)                                                        !
!                                                                      !
!  TABLO input file for the Cobb-Douglas version of PROTO, a simple    !
!  static general equilibrium model.                                   !
!----------------------------------------------------------------------!

EQUATION    (default=levels);
VARIABLE    (default=levels);
FORMULA     (default=initial);
COEFFICIENT (default=parameter);


!----------------------------------------------------------------------!
!  These are the parameters:                                           !
!----------------------------------------------------------------------!

COEFFICIENT a     ;  FORMULA a     = 0.285;
COEFFICIENT alpha ;  FORMULA alpha = 2    ;
COEFFICIENT g     ;  FORMULA g     = 0.5  ;


!----------------------------------------------------------------------!
!  Here are the variables.  No distinction needs to be made between    !
!  endogenous and exogenous variables since that is determined when    !
!  the model is actually simulated.                                    !
!----------------------------------------------------------------------!

VARIABLE   h   # Total endowment of hours        #;
VARIABLE   p   # Numeraire price                 #;
VARIABLE   y   # Income                          #;
VARIABLE   w   # Wage rate paid by firms         #;
VARIABLE   s   # Subsidy to households           #;
VARIABLE   c   # Quantity consumed               #;
VARIABLE   l   # Labor supplied                  #;
VARIABLE   j   # Leisure consumed                #;
VARIABLE   q   # Quantity produced               #;
VARIABLE  pc   # Purchase P of good to HH        #;
VARIABLE  px   # Purchase P of intermed to firms #;
VARIABLE  tc   # Tax rate on consumption         #;
VARIABLE ptw   # Power of tax rate on wages      #;
VARIABLE ptx   # Power of tax rate on int        #;
VARIABLE   u   # Utility                         #;
VARIABLE  wh   # After tax wage to households    #;
VARIABLE  wl   # Walras law check                #;
VARIABLE   x   # Intermediate demand             #;


!----------------------------------------------------------------------!
!  Initial values of exogenous variables                               !
!----------------------------------------------------------------------!

FORMULA h   = 100.0;
FORMULA tc  = 0.200;
FORMULA ptx = 1    ;
FORMULA ptw = 1    ;
FORMULA p   = 1.000;


!----------------------------------------------------------------------!
!  Initial values of endogenous variables for linearization.  These    !
!  were taken from the Ox version of the model.                        !
!----------------------------------------------------------------------!

FORMULA c  =  24.93438;
FORMULA l  =  24.93438;
FORMULA q  =  49.86877;
FORMULA s  =   4.98688;
FORMULA w  =   1.00000;
FORMULA x  =  24.93438;
FORMULA y  = 104.98688;


!----------------------------------------------------------------------!
!  Other initial values that can be computed from the numbers above    !
!----------------------------------------------------------------------!

FORMULA wh = w*ptw;
FORMULA wl = 1;


!----------------------------------------------------------------------!
!  Finally, here are the equations:                                    !
!----------------------------------------------------------------------!

EQUATION eq00     y = wh*h + s                                ;
EQUATION eq01  pc*c = a*y                                     ;
EQUATION eq02  wh*j = (1-a)*y                                 ;
EQUATION eq03  wh*l = a*y - s                                 ;
EQUATION eq04     l = (q/alpha)*( (1-g)*px/(g*w) )^g          ;
EQUATION eq05     x = (q/alpha)*( g*w/((1-g)*px) )^(1-g)      ;
EQUATION eq06     p = (1/alpha)*( px/g )^g*( w/(1-g) )^(1-g)  ;
EQUATION eq07     s = tc*p*c + (ptx-1)*p*x + (1-ptw)*w*l      ;
EQUATION eq08    pc = p*(1+tc)                                ;
EQUATION eq09    px = p*ptx                                   ;
EQUATION eq10    wh = w*ptw                                   ;
EQUATION eq11     u = c^a*j^(1-a)                             ;
EQUATION eq12    wl = q / (x + c)                             ;